#CLASS {map} KILL
#CLASS {map} OPEN

#ACTION {^<MAPEND>$}
{
	#line gag;
	#variable getmap 0;
	#if {$autoscan}
	{
		scan;
	};
}
{1}

#alias {autoscan}
{
        #IF {"%0" != ""}
        {
                #show <069>Reminder: autoscan doesn't take arguments.<099>
        };
        #if {$autoscan == 0}
        {
                #var autoscan 1;
                #show <069>Autoscan: <129>ON<099>
        };
        #ELSEIF {$autoscan == 1}
        {
                #var autoscan 0;
                #show <069>Autoscan: <099>Off
        };
        #ELSE
        {
                #show <069>Something went wrong with the autoscan alias in map.tt<099>
        }
}

#ACTION {^<MAPSTART>$}
{
	#variable getmap 1;
	#line gag
}
{1}

#action {^\{roomchars\}} 
{
	#var getchar 1;
	#line gag;
	#line log {$dir/chars} {------<179>[ $GMCP[ROOM][INFO][name] ]<099>}
}

#action {^\{/roomchars\}} 
{
	#var getchar 0;
	#line gag;
	#line log {$dir/chars} {\n}
}

#ACTION {~%0}
{
	#if {$getmap}
	{
		#line log {$dir/minimap} {%0};
		#if {!$showmap}
		{
			#line gag
		}
	};
	#elseif {$getchar}
	{
		#line log {$dir/chars} {%0}
	}
	
}
{9999}


#CLASS {map} CLOSE