discworld-tintin/src/aliases.tin

#ALIAS {setsize} {rows 300;cols 148};
#ALIAS {setmsize} {rows 300;cols 60};

#ALIAS {^clear$} {
    #system {tput clear};
    #split {2} {1};
    setsize;
};

#ALIAS {htop} {
   #system {htop}; 
};

#ALIAS {rst} {
    #read {config.tin};
    setsize;
    shields;
};

#ALIAS {wiki} {
    #system {w3m https://dwwiki.mooo.com/w/index.php?search=%0};
    #split {2} {1};
    setsize;
};

#ALIAS {colourpalette}
{
	#foreach {a;b;c;d;e;f} {cnt1}
	{
		#foreach {a;b;c;d;e;f} {cnt2}
		{
			#var result <000>;
			#foreach {a;b;c;d;e;f} {cnt3}
			{
				#var result $result  <$cnt1$cnt2$cnt3> <<888>$cnt1$cnt2$cnt3><088>
			};
			#showme $result
		}
	}
}

#ALIAS {minesolve %1 %2 %3} {
    #var {total} {%1};
    #var {hammer} {%2};
    #var {pickaxe} {%3};

    #var {solvecommand} {python3 -c 'import math; t,p,h = $total,$pickaxe,$hammer; pu,hu = int(math.floor(t/p)+1), int(math.floor(t/h)+1); print(*sorted([(i, j) for j in range(0,hu) for i in range(0,pu) if ((i*p) + (j*h) == t)], key=lambda t: t[1])[0]);'};
    #script {result} {$solvecommand};

    #replace {result[1]} { } {;};
    #list {solution} {create} {$result[1]};

    #format {minesolvedisplay} {<149>[MineSolver] Best solution is <139>%d<149> pickaxe strikes and <139>%d<149> hammer chips for a total of <159>%f<149> inches.<099>} {$solution[1]} {$solution[2]} {$total};
    #echo {$minesolvedisplay};
};


#nop Resizing aliases for when we're in "cols 999" mode;
#ALIAS {^skills%1} {
    #send {cols 130};
    #send {skills %1};
    #send {cols 999};
};
#ALIAS {^{speak|language}$} {
    #send {cols 130};
    #send {speak};
    #send {cols 999};
};
#ALIAS {^spells$} { #send {cols 130}; #send {spells}; #send {cols 999}; };
#ALIAS {^rituals$} { #send {cols 130}; #send {rituals}; #send {cols 999}; };

#ALIAS {^group status$} { #send {cols 130}; #send {group status}; #send {cols 999}; };

#ALIAS {^{who$|who (.+)$}} {
    #send {cols 130};
    #send {%0};
    #send {cols 999};
};
#ALIAS {^help %1} {
    #send {cols 130};
    #send {help %1};
    #send {cols 999};
};
#ALIAS {^nickname$} {
    #send {cols 130};
    #send {nickname};
    #send {cols 999};
};